音影先锋亚洲天堂网|电影世界尽头的爱完整版播放|国产 熟女 91|高清无码免费观看欧美日韩|韩国一区二区三区黄色录像|美女亚洲加勒比在线|亚洲综合网 开心五月|7x成人在线入口|成人网站免费日韩毛片区|国产黄片?一级?二级?三级

登錄 免費注冊 首頁 | 行業(yè)黑名單 | 幫助
維庫電子市場網(wǎng)
IC 電子元器件 電子資訊 技術(shù)資料
技術(shù)交流 | 電路欣賞 | 工控天地 | 數(shù)字廣電 | 通信技術(shù) | 電源技術(shù) | 測控之家 | EMC技術(shù) | ARM技術(shù) | EDA技術(shù) | PCB技術(shù) | 嵌入式系統(tǒng)
驅(qū)動編程 | 集成電路 | 器件替換 | 模擬技術(shù) | 新手園地 | 單 片 機(jī) | DSP技術(shù) | MCU技術(shù) | IC 設(shè)計 | IC 產(chǎn)業(yè) | CAN-bus/DeviceNe

[分享]MCS-51單片機(jī)實用子程序庫
作者：liuli9230　欄目：單片機(jī)
目前已有若干版本的子程序庫公開發(fā)表,它們各有特色。筆者在1988年也編制了兩個
子程序庫(定點子程序庫和浮點子程序庫),并在相容性、透明性、容錯性和算法優(yōu)化方面作了一些工作。本程序庫中的開平方算法為筆者研究的快速逼近算法,它能達(dá)到牛頓迭代法同樣的精度,而速度加快二十倍左右,超過雙字節(jié)定點除法的速度。經(jīng)過八年來全國廣大用戶的實際使用,反饋了不少信息,陸續(xù)擴(kuò)充了一些新的子程序,糾正了一些隱含錯誤,成為現(xiàn)在這個最新版本。
本子程序庫對《單片機(jī)應(yīng)用程序設(shè)計技術(shù)》一書附錄中的子程序庫作了重大修訂:
(1)按當(dāng)前流行的以 IBM PC 為主機(jī)的開發(fā)系統(tǒng)對匯編語言的規(guī)定,將原子程序庫
的標(biāo)號和位地址進(jìn)行了調(diào)整,讀者不必再進(jìn)行修改,便可直接使用。
(2)對浮點運算子程序庫進(jìn)行了進(jìn)一步的測試和優(yōu)化,對十進(jìn)制浮點數(shù)和二進(jìn)制浮
點數(shù)的相互轉(zhuǎn)換子程序進(jìn)行了徹底改寫,提高了運算精度和可靠性。
(3)新增添了若干個浮點子程序(傳送、比較、清零、判零等),使編寫數(shù)據(jù)處理
程序的工作變得更簡單直觀。
在使用說明中開列了最主要的幾項:標(biāo)號、入口條件、出口信息、影響資源、堆棧需求,各項目的意義請參閱《單片機(jī)應(yīng)用程序設(shè)計技術(shù)》第六章 6.3.7 節(jié)的內(nèi)容。程序清單中開列了四個欄目:標(biāo)號、指令、操作數(shù)、注釋。為方便讀者理解,注釋盡力詳細(xì)。
子程序庫的使用方法如下:
1．將子程序庫全部內(nèi)容鏈接在應(yīng)用程序之后,統(tǒng)一編譯即可。優(yōu)點是簡單方便,缺點是程序太長,大量無關(guān)子程序也包含在其中。
2．僅將子程序庫中的有關(guān)部分內(nèi)容鏈接在應(yīng)用程序之后,統(tǒng)一編譯即可。有些子程序需要調(diào)用一些低級子程序,這些低級子程序也應(yīng)該包含在內(nèi)。優(yōu)點是程序緊湊,缺點是
需要對子程序庫進(jìn)行仔細(xì)刪節(jié)。

(一)MCS-51定點運算子程序庫及其使用說明
定點運算子程序庫文件名為DQ51.ASM,為便于使用,先將有關(guān)約定說明如下:
1．多字節(jié)定點操作數(shù):用[R0]或[R1]來表示存放在由R0或R1指示的連續(xù)單元中的數(shù)據(jù)。地址小的單元存放數(shù)據(jù)的高字節(jié)。例如:[R0]=123456H,若(R0)=30H,則(30H)=12H,
(31H)=34H,(32H)=56H。
2．運算精度:單次定點運算精度為結(jié)果最低位的當(dāng)量值。
3．工作區(qū):數(shù)據(jù)工作區(qū)固定在PSW、A、B、R2~R7,用戶只要不在工作區(qū)中存放無
關(guān)的或非消耗性的信息,程序就具有較好的透明性。

(1) 標(biāo)號: BCDA功能:多字節(jié)BCD碼加法

入口條件:字節(jié)數(shù)在R7中,被加數(shù)在[R0]中,加數(shù)在[R1]中。
出口信息:和在[R0]中,最高位進(jìn)位在CY中。
影響資源:PSW、A、R2 堆棧需求: 2字節(jié)

BCDA: MOV A,R7 ;取字節(jié)數(shù)至R2中
MOV R2,A
ADD A,R0 ;初始化數(shù)據(jù)指針
MOV R0,A
MOV A,R2
ADD A,R1
MOV R1,A
CLR C
BCD1: DEC R0 ;調(diào)整數(shù)據(jù)指針
DEC R1
MOV A,@R0
ADDC A,@R1 ;按字節(jié)相加
DA A ;十進(jìn)制調(diào)整
MOV @R0,A ;和存回[R0]中
DJNZ R2,BCD1 ;處理完所有字節(jié)
RET

(2) 標(biāo)號: BCDB功能:多字節(jié)BCD碼減法

入口條件:字節(jié)數(shù)在R7中,被減數(shù)在[R0]中,減數(shù)在[R1]中。
出口信息:差在[R0]中,最高位借位在CY中。
影響資源:PSW、A、R2、R3 堆棧需求: 6字節(jié)

BCDB: LCALL NEG1 ;減數(shù)[R1]十進(jìn)制取補(bǔ)
LCALL BCDA ;按多字節(jié)BCD碼加法處理
CPL C ;將補(bǔ)碼加法的進(jìn)位標(biāo)志轉(zhuǎn)換成借位標(biāo)志
MOV F0,C ;保護(hù)借位標(biāo)志
LCALL NEG1 ;恢復(fù)減數(shù)[R1]的原始值
MOV C,F0 ;恢復(fù)借位標(biāo)志
RET
NEG1: MOV A,R0 ;[R1]十進(jìn)制取補(bǔ)子程序入口
XCH A,R1 ;交換指針
XCH A,R0
LCALL NEG ;通過[R0]實現(xiàn)[R1]取補(bǔ)
MOV A,R0
XCH A,R1 ;換回指針
XCH A,R0
RET


(3) 標(biāo)號: NEG功能:多字節(jié)BCD碼取補(bǔ)

入口條件:字節(jié)數(shù)在R7中,操作數(shù)在[R0]中。
出口信息:結(jié)果仍在[R0]中。
影響資源:PSW、A、R2、R3 堆棧需求: 2字節(jié)

NEG: MOV A,R7 ;取(字節(jié)數(shù)減一)至R2中
DEC A
MOV R2,A
MOV A,R0 ;保護(hù)指針
MOV R3,A
NEG0: CLR C
MOV A,#99H
SUBB A,@R0 ;按字節(jié)十進(jìn)制取補(bǔ)
MOV @R0,A ;存回[R0]中
INC R0 ;調(diào)整數(shù)據(jù)指針
DJNZ R2,NEG0 ;處理完(R2)字節(jié)
MOV A,#9AH ;最低字節(jié)單獨取補(bǔ)
SUBB A,@R0
MOV @R0,A
MOV A,R3 ;恢復(fù)指針
MOV R0,A
RET

(4) 標(biāo)號: BRLN功能:多字節(jié)BCD碼左移十進(jìn)制一位(乘十)

入口條件:字節(jié)數(shù)在R7中,操作數(shù)在[R0]中。
出口信息:結(jié)果仍在[R0]中,移出的十進(jìn)制最高位在R3中。
影響資源:PSW、A、R2、R3 堆棧需求: 2字節(jié)

BRLN: MOV A,R7 ;取字節(jié)數(shù)至R2中
MOV R2,A
ADD A,R0 ;初始化數(shù)據(jù)指針
MOV R0,A
MOV R3,#0 ;工作單元初始化
BRL1: DEC R0 ;調(diào)整數(shù)據(jù)指針
MOV A,@R0 ;取一字節(jié)
SWAP A ;交換十進(jìn)制高低位
MOV @R0,A ;存回
MOV A,R3 ;取低字節(jié)移出的十進(jìn)制高位
XCHD A,@R0 ;換出本字節(jié)的十進(jìn)制高位
MOV R3,A ;保存本字節(jié)的十進(jìn)制高位
DJNZ R2,BRL1 ;處理完所有字節(jié)
RET

(5) 標(biāo)號: MULD功能:雙字節(jié)二進(jìn)制無符號數(shù)乘法

入口條件:被乘數(shù)在R2、R3中,乘數(shù)在R6、R7中。
出口信息:乘積在R2、R3、R4、R5中。
影響資源:PSW、A、B、R2~R7 堆棧需求: 2字節(jié)

MULD: MOV A,R3 ;計算R3乘R7
MOV B,R7
MUL AB
MOV R4,B ;暫存部分積
MOV R5,A
MOV A,R3 ;計算R3乘R6
MOV B,R6
MUL AB
ADD A,R4 ;累加部分積
MOV R4,A
CLR A
ADDC A,B
MOV R3,A
MOV A,R2 ;計算R2乘R7
MOV B,R7
MUL AB
ADD A,R4 ;累加部分積
MOV R4,A
MOV A,R3
ADDC A,B
MOV R3,A
CLR A
RLC A
XCH A,R2 ;計算R2乘R6
MOV B,R6
MUL AB
ADD A,R3 ;累加部分積
MOV R3,A
MOV A,R2
ADDC A,B
MOV R2,A
RET
(6) 標(biāo)號: MUL2功能:雙字節(jié)二進(jìn)制無符號數(shù)平方

入口條件:待平方數(shù)在R2、R3中。
出口信息:結(jié)果在R2、R3、R4、R5中。
影響資源:PSW、A、B、R2~R5 堆棧需求: 2字節(jié)

MUL2: MOV A,R3 ;計算R3平方
MOV B,A
MUL AB
MOV R4,B ;暫存部分積
MOV R5,A
MOV A,R2 ;計算R2平方
MOV B,A
MUL AB
XCH A,R3 ;暫存部分積,并換出R2和R3
XCH A,B
XCH A,R2
MUL AB ;計算2×R2×R3
CLR C
RLC A
XCH A,B
RLC A
JNC MU20
INC R2 ;累加溢出量
MU20: XCH A,B ;累加部分積
ADD A,R4
MOV R4,A
MOV A,R3
ADDC A,B
MOV R3,A
CLR A
ADDC A,R2
MOV R2,A
RET

(7) 標(biāo)號: DIVD功能:雙字節(jié)二進(jìn)制無符號數(shù)除法

入口條件:被除數(shù)在R2、R3、R4、R5中,除數(shù)在R6、R7中。
出口信息:OV=0 時,雙字節(jié)商在R2、R3中,OV=1 時溢出。
影響資源:PSW、A、B、R1~R7 堆棧需求: 2字節(jié)

DIVD: CLR C ;比較被除數(shù)和除數(shù)
MOV A,R3
SUBB A,R7
MOV A,R2
SUBB A,R6
JC DVD1
SETB OV ;溢出
RET
DVD1: MOV B,#10H ;計算雙字節(jié)商
DVD2: CLR C ;部分商和余數(shù)同時左移一位
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
XCH A,R2
RLC A
XCH A,R2
MOV F0,C ;保存溢出位
CLR C
SUBB A,R7 ;計算(R2R3-R6R7)
MOV R1,A
MOV A,R2
SUBB A,R6
ANL C,/F0 ;結(jié)果判斷
JC DVD3
MOV R2,A ;夠減,存放新的余數(shù)
MOV A,R1
MOV R3,A
INC R5 ;商的低位置一
DVD3: DJNZ B,DVD2 ;計算完十六位商(R4R5)
MOV A,R4 ;將商移到R2R3中
MOV R2,A
MOV A,R5
MOV R3,A
CLR OV ;設(shè)立成功標(biāo)志
RET

(8) 標(biāo)號: D457功能:雙字節(jié)二進(jìn)制無符號數(shù)除以單字節(jié)二進(jìn)制數(shù)

入口條件:被除數(shù)在R4、R5中,除數(shù)在R7中。
出口信息:OV=0 時,單字節(jié)商在R3中,OV=1 時溢出。
影響資源:PSW、A、R3~R7 堆棧需求: 2字節(jié)

D457: CLR C
MOV A,R4
SUBB A,R7
JC DV50
SETB OV ;商溢出
RET
DV50: MOV R6,#8 ;求平均值(R4R5/R7-→R3)
DV51: MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DV52
MOV R4,A
DV52: CPL C
MOV A,R3
RLC A
MOV R3,A
DJNZ R6,DV51
MOV A,R4 ;四舍五入
ADD A,R4
JC DV53
SUBB A,R7
JC DV54
DV53: INC R3
DV54: CLR OV
RET
(9) 標(biāo)號: DV31功能:三字節(jié)二進(jìn)制無符號數(shù)除以單字節(jié)二進(jìn)制數(shù)

入口條件:被除數(shù)在R3、R4、R5中,除數(shù)在R7中。
出口信息:OV=0 時,雙字節(jié)商在R4、R5中,OV=1 時溢出。
影響資源:PSW、A、B、R2~R7 堆棧需求: 2字節(jié)

DV31: CLR C
MOV A,R3
SUBB A,R7
JC DV30
SETB OV ;商溢出
RET
DV30: MOV R2,#10H ;求R3R4R5/R7-→R4R5
DM23: CLR C
MOV A,R5
RLC A
MOV R5,A
MOV A,R4
RLC A
MOV R4,A
MOV A,R3
RLC A
MOV R3,A
MOV F0,C
CLR C
SUBB A,R7
ANL C,/F0
JC DM24
MOV R3,A
INC R5
DM24: DJNZ R2,DM23
MOV A,R3 ;四舍五入
ADD A,R3
JC DM25
SUBB A,R7
JC DM26
DM25: INC R5
MOV A,R5
JNZ DM26
INC R4
DM26: CLR OV
RET ;商在R4R5中


(10) 標(biāo)號: MULS功能:雙字節(jié)二進(jìn)制有符號數(shù)乘法(補(bǔ)碼)

入口條件:被乘數(shù)在R2、R3中,乘數(shù)在R6、R7中。
出口信息:乘積在R2、R3、R4、R5中。
影響資源:PSW、A、B、R2~R7 堆棧需求: 4字節(jié)

MULS: MOV R4,#0 ;清零R4R5
MOV R5,#0
LCALL MDS ;計算結(jié)果的符號和兩個操作數(shù)的絕對值
LCALL MULD ;計算兩個絕對值的乘積
SJMP MDSE ;用補(bǔ)碼表示結(jié)果

(11) 標(biāo)號: DIVS功能:雙字節(jié)二進(jìn)制有符號數(shù)除法(補(bǔ)碼)

入口條件:被除數(shù)在R2、R3、R4、R5中,除數(shù)在R6、R7中。
出口信息:OV=0時商在R2、R3中,OV=1時溢出。
影響資源
2樓： >>參與討論
liuli9230

大家都來看看,,很實用
3樓： >>參與討論
275124957

確實很好,,謝謝啦,,兄弟
參與討論
昵稱：
討論內(nèi)容：
 
 
相關(guān)帖子
基于89C51單片機(jī)試驗板
[注意]C51的一些誤區(qū)和注意事項
[推薦]初學(xué)單片機(jī)者必備
[原創(chuàng)]12864屏的萬年歷
請問這句C語言是什么意思？#define TP (0<<7) | (0<<3...
免費注冊為維庫電子開發(fā)網(wǎng)會員，參與電子工程師社區(qū)討論，點此進(jìn)入

Copyright © 1998-2006 m.58mhw.cn 浙ICP證030469號